void speaker_test() {
sound test;

// Load the narrator saying "left". You can replace this with tts, if you prefer.
test.load("left.wav");
test.play_wait();

// Using an arbitrary sound:
test.stream("test.wav");
test.pan=-100;
test.play_wait();

// Say "right". Again, you can replace the following two lines with tts if you prefer.
test.stream("right.wav");
test.pan=0;
test.play_wait();

test.stream("test.wav");
test.pan=100;
test.play_wait();
}

#include "dynamic_menu.bgt"

// There are two ways you could set up constants for this. This is probably the easiest, but it'd make me kinda nervous using it for something like this:

enum difficulties {
 easy, normal, hard, hardest
};

// Create a variable to keep track of the difficulty. We're using an int, since it's often useful to put the difficulty into some calculations at some point.
int difficulty=normal;

// This function returns true if the player successfully picked a difficulty, false if they hit escape or if an error occurred.
bool select_difficulty() {
dynamic_menu difmenu;

// I'll use tts for these. Using recordings instead is a matter of removing the _tts from each one, and replacing the text between quotes with the appropriate filename.
difmenu.add_item_tts("easy", "" + easy);
difmenu.add_item_tts("normal", "" + normal);
difmenu.add_item_tts("hard", "" + hard);
difmenu.add_item_tts("hardest", "" + hardest);

int result=difmenu.run("Choose difficulty", true);
// If you used recordings instead, you'd do something like int result=difmenu.run("select_difficulty.wav", false);

// There is a shortcut, here, if you know that the values are in ascending order. The rest of this example will be the long way, but if you want, you could just do this:
// if(result<=0) return false;
// difficulty=result-1; // Assuming the difficulty constants start at 0, otherwise just say difficulty=result.
// return true;

// The longer way:
if(difmenu.get_item_name(result)=="") return false;

int new_difficulty=string_to_number(difmenu.get_item_name(result));

// Check for valid results. You can skip this part if you care more about having a number than that it is necessarily one of our constants.
if(new_difficulty!= easy and new_difficulty!=normal and new_difficulty!=hard and new_difficulty!=hardest) return false;

// At this point, everything worked, so we set the global variable to the selection, and the program will remember it until we change it again.
difficulty=new_difficulty;
return true;
}